I-Nex/dists/PKGBUILD

# Maintainer: eloaders <eloaders at linux dot pl>

pkgname=i-nex
pkgver=7.6.0
pkgrel=1
pkgdesc="System information tool like hardinfo, sysinfo"
arch=('i686' 'x86_64')
url="http://i-nex.linux.pl/"
license=('LGPL3')
depends=('gambas3-runtime' 
	 	 'gambas3-gb-image' 
	 	 'gambas3-gb-form'
         'gambas3-gb-desktop'
         'gambas3-gb-qt5'
         'gambas3-gb-desktop-x11'
         'pastebinit' 
         'libcpuid-git'
         'xorg-server-utils' 
         'lsb-release')
makedepends=('gambas3-devel' 'gcc' 'git')
source=("$pkgname::git+https://github.com/eloaders/I-Nex.git")
sha256sums=('SKIP')
provides=('i-nex' 'i-nex-bzr' 'i-nex-dev')
conflicts=('i-nex' 'i-nex-bzr' 'i-nex-dev')
pkgver() {
  cd $pkgname
  git describe --tags | tr - .
}
prepare() {
  cd $pkgname
  # make it dynamic
  sed -i -e 's|^STATIC.*|STATIC = false|' i-nex.mk
  sed -i -e 's|^UDEV_RULES_DIR.*|UDEV_RULES_DIR = /usr/lib/udev/rules.d|' i-nex.mk
  cd I-Nex
  autoreconf -i
}
 
build() {
  cd $pkgname
  cd I-Nex
  ./configure --prefix=/usr
  cd ..
  make
}
 
package() {
  cd $pkgname
  make install DESTDIR="$pkgdir"
}